10 POKE53281,6:POKE53280,14:PRINT"[154]"
20 OPEN 2,0,2:CH$=CHR$(128+13):PRINTCHR$(142)
30 L1$="[154]":L2$="":L3$="[158]":Q$=" ":QU$="  ":FR$="F"
40 DIMA$(120,3)
50 PRINT"[147]      LATEINISCHE DEKLINATION"
60 PRINT"      [163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
70 PRINT"                    WINFRIED FLIKSCHUH"
80 PRINT"      AUTOR UND     ALBERTSTR.5"
90 PRINT"   COPYRIGHT(1986): 5430 MONTABAUR"
100 PRINT"                    TEL.:02602-2533"
110 PRINT"[158]    BITTE WARTEN!"
120 N=111
130 FOR K=1TON
140 READ A$(K,O),A$(K,1),A$(K,2),A$(K,3)
150 NEXT
160 PRINTCHR$(14):PRINT"[154][145][145][196]IESES [208]ROGRAMM IST DEM [208]ROGRAMMPAKET"
170 PRINT"[207][205][206][201][198][204][197][216] ENTNOMMEN, DAS AUSSER DER [196]EK-"
180 PRINT"LINATION AEHNLICHE [213]EBUNGEN ZUR [203]ONJU-"
190 PRINT"GATION, ZUM [208]RONOMEN UND ZU DEN [211]TAMM-"
200 PRINT"FORMEN ENTHAELT. [193]USSERDEM ERLAUBT"
210 PRINT"[207][205][206][201][198][204][197][216] DIE [193]NLAGE EIGENER [196]ATEIEN UND"
220 PRINT"KANN JEDES BELIEBIGE [211]UBSTANTIV, [193]DJEK-"
230 PRINT"TIV ODER [214]ERB BEUGEN. [197]S IST ZUM [208]REIS"
240 PRINT"VON [196][205] 36,- (+ [196][205] 3.- [214]ERSANDKOSTEN)"
250 PRINT"BEIM [214]ERFASSER ERHAELTLICH([211]TAND 1988)."
270 GOSUB6610
280 M$="[147][197][210][203][204][193][197][210][213][206][199][197][206]":PRINTM$
290 PRINTCHR$(14);" [196]IESES [208]ROGRAMM DIENT ZUR [197]INUEBUNG DER";
300 PRINT" LATEINISCHEN [196]EKLINATIONSFORMEN UND"
310 PRINT" ENTHAELT [211]UBSTANTIVE DER"
320 PRINTL2$;"    [193]-,[207]-,[197]-,[213]-,[201]-";"[154]UND"
330 PRINT"KONS.";"[154][196]EKL.(INCL.[205]ISCHFORM)"
340 PRINT" [194]EI DER [198]ORMENBESTIMMUNG IST AUF KOR-"
350 PRINT" REKTE [193]NWENDUNG DER [193]BKUERZUNGEN ZU "
360 PRINT" ACHTEN, UND ZWAR:"
370 PRINT"         [199][197][206].[211].[196][193][212].[211].[193][203][203].[211].[193][194][204].[211]."
380 PRINT"[206][207][205].[208][204].[199][197][206].[208][204].[196][193][212].[208][204].[193][203][203].[208][204].[193][194][204].[208][204]."
390 PRINT"[154][196]A ES SCHWERER IST,EINEM [195]OMPUTER EINI-";
400 PRINT" GE [199]RUNDKENNTNISSE IM [204]ATEINISCHEN ZU"
410 PRINT" VERMITTELN ALS EINEM [211]CHUELER,BILDET"
420 PRINT" ODER VERLANGT DAS [208]ROGRAMM AUCH [198]ORMEN"
430 PRINT" WIE 'FUGA FIRMA'-[214]ERZEIHUNG!"
440 PRINT"[194][201][212][212][197] [212][193][211][212][197][160][196][210][213][197][195][203][197][206]"
450 POKE198,0:WAIT198,1:GETA$
460 PRINT"[147]":P=0:Q$=" ":MM$=""
470 POKE53280,14:PRINT"[154]"
480 PRINTCHR$(142);"       LATEINISCHE DEKLINATION"
490 PRINT"       [163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
500 PRINT"  HAUPTMENUE :"
510 PRINT"  [163][163][163][163][163][163][163][163][163][163][163][163]"
520 PRINT"[160][160][160]    [1] DEKLINATIONSUEBUNG"
530 PRINT"       [2] FORMEN BILDEN"
540 PRINT"       [3] FORMEN BESTIMMEN"
550 PRINT"[160][160][160]    [4] FORMEN BILDEN LASSEN"
560 PRINT"       [5] DEKLINATIONSTABELLEN"
570 PRINT"       [6] ENDE"
580 POKE198,0:WAIT198,1:GETEF$:EF=VAL(EF$)
590 IFEF>0ANDEF<7THEN ON EF GOTO 610,1190,1430,2170,4440,5310
600 GOTO580
610 POKE53280,13
620 QA$="-":O$="":B$="":PO$=CHR$(16):AS$="":M$="[147][154]    DEKLINATIONSUEBUNG[146]"
630 PRINTM$:PRINT"UEBUNG (U)  ODER TABELLE (T) ";:INPUT E3$
640 INPUT "MIT ADJEKTIV (J/N)";I1$
650 PRINT "GEWUENSCHTES SUBSTANTIV"
660 PRINT"[158]  ";:INPUT#2,S$:PRINTCH$
670 IF I1$<>"J"THEN 700
680 PRINT "[154]GEWUENSCHTES ADJEKTIV (MASK.S.)"
690 PRINT"[158]  ";:INPUT#2,AJ$:PRINTCH$
700 PRINTL1$:GOSUB 4790
710 IFS$="N"THEN460
720 GOSUB 4200
730 IF AS$="P"THENNS$=A$(X,0)
740 PRINTM$:PRINT"";NS$;"[146]":PRINT
750 IF E3$="T"THENPRINT" BITTE ETWAS WARTEN"
760 FOR Y=0TO9
770 IF Y=0THENSA$=NS$:C$="NOM.S.":C0$=C$:GOTO900
780 IF AS$="S"AND Y>4THEN980
790 GOSUB2430
800 IF AS$="P"ANDY<5THENSA$="":GOTO970
810 IF Y=1THEN C1$=C$:D1$=SA$:GOTO900
820 IF Y=2THEN C2$=C$:D2$=SA$:GOTO900
830 IF Y=3THEN C3$=C$:D3$=SA$:GOTO900
840 IF Y=4THEN C4$=C$:D4$=SA$:GOTO900
850 IF Y=5THEN C5$=C$:D5$=SA$:GOTO900
860 IF Y=6THEN C6$=C$:D6$=SA$:GOTO900
870 IF Y=7THEN C7$=C$:D7$=SA$:GOTO900
880 IF Y=8THEN C8$=C$:D8$=SA$:GOTO900
890 IF Y=9THEN C9$=C$:D9$=SA$
900 IF E3$="T"ORAS$="P"ANDY<5THEN 970
910 IFY=3ANDA$(X,3)="N"THENPRINT
920 PRINTL2$;Q$;C$;":";TAB(15)L3$;:INPUT#2,DC$:PRINTCH$;L1$;
930 IF DC$=SA$THEN970
940 PRINT" HILFE:";QA$+B$;QA$+O$;TAB(15)L3$;:INPUT#2,DC$:PRINTCH$;L1$
950 IF DC$=SA$THENPRINT"[145][145][145]":GOTO970
960 PRINT" [145][145]DIE LOESUNG:  ";L2$;TAB(15)SA$;L1$:PRINT"[145][145]"
970 NEXTY
980 PRINT"LEERTASTE DRUECKEN"
990 GET A5$:IFA5$=""THEN990
1000 IF AS$="P"THEN PRINT M$:GOTO1040
1010 PRINT M$:PRINT"";NS$;"[146]"
1020 PRINTQU$;C0$;":  ";NS$:PRINTQU$;C1$;":  ";D1$:PRINTQU$;C2$;":  "D2$
1030 PRINTQU$;C3$;":  ";D3$:PRINTQU$;C4$;":  ";D4$:IFAS$="S"THEN1060
1040 PRINTQU$;C5$;": ";D5$:PRINTQU$;C6$;": ";D6$
1050 PRINTQU$;C7$;": ";D7$:PRINTQU$;C8$;": ";D8$:PRINTQU$;C9$;": ";D9$
1060 INPUT"AUSDRUCKEN (J/N)";E4$:IF E4$<>"J"THEN 1170
1070 INPUT"DRUCKER BETRIEBSBEREIT (J/N)";E5$:IFE5$<>"J"THEN1060
1080 E4$="":E5$="":OPEN 7,4,0
1090 IF AS$="P"THEN D1$="":D2$="":D3$="":D4$=""
1100 PRINT#7,CHR$(14);PO$;"22";NS$;CHR$(15)
1110 PRINT#7,PO$;"05";C0$;": ";NS$;PO$;"40";C5$;": ";D5$
1120 PRINT#7,PO$;"05";C1$;": ";D1$;PO$;"40";C6$;": ";D6$
1130 PRINT#7,PO$;"05";C2$;": ";D2$;PO$;"40";C7$;": ";D7$
1140 PRINT#7,PO$;"05";C3$;": ";D3$;PO$;"40";C8$;": ";D8$
1150 PRINT#7,PO$;"05";C4$;": ";D4$;PO$;"40";C9$;": ";D9$
1160 CLOSE7
1170 GOSUB 5030
1180 GOTO620
1190 M$="[154][147]     FORMEN BILDEN[146]":PRINTM$:POKE53280,11
1200 GOSUB4350
1210 P=0:Q$=" ":SA$="":PRINTM$
1220 GOSUB5070:INPUT "  WIEVIELE AUFGABEN";H
1230 PRINTM$
1240 FOR I=1TOH
1250 GOSUB4050
1260 PRINT"";NS$
1270 GOSUB2430
1280 IF C$="AKK.S" AND A$(X,3)="N"THEN SA$=NS$
1290 IFMM$="M"THENPRINT"  ";C$:GOSUB5100:GOTO1380
1300 PRINT"";C$;": [158]";:INPUT#2,D$
1310 PRINTCH$
1320 IF D$=SA$ THEN1370
1330 IFPP>9THEN1350
1340 R=R+1:V$(R)=C$:R$(R)=SA$:PP=PP+1
1350 PRINT"LEIDER FALSCH! RICHTIG IST:"
1360 PRINT"";SA$;"[146]":GOTO1380
1370 GOSUB5220:PRINT"RICHTIG!":P=P+1
1380 GOSUB 5460
1390 PRINTM$
1400 NEXTI
1410 GOSUB4920
1420 GOTO1210
1430 M$="[154][147]     FORMEN BESTIMMEN[146]":PRINTM$:POKE53280,15
1440 GOSUB4350
1450 P=0:SA$="":PRINTM$
1460 GOSUB5070:INPUT "  WIEVIELE AUFGABEN";H
1470 PRINT M$
1480 FOR I=1 TO H
1490 SA$="":NS$="":CD$="":F$=""
1500 GOSUB4050
1510 GOSUB2430
1520 PRINT"";SA$:IFMM$="M"THENGOSUB5100:GOTO2120
1530 PRINT"  NOMINATIV (S.): [158]";:INPUT#2,G$:PRINTCH$
1540 IF G$<>NS$THEN1960
1550 PRINT"  KASUS: [158]";:INPUT#2,F$:PRINTCH$
1560 IF F$="DAT.PL."ORF$="ABL.PL."THEN1820
1570 IF A$(X,3)="N"THEN1640
1580 IF AP$>"B"AND AD$<>"B"THEN1640
1590 IFAP$="A"ANDA$(X,3)="M"ANDAD$="B"THEN1790
1600 IFAP$="B"ANDA$(X,3)="F"ANDAD$="B"THEN1790
1610 IFAP$="H"ANDA$(X,3)="M"ANDI1$="J"THEN1800
1620 IF AP$="B"THEN 1720
1630 GOTO 1680
1640 IF F$="NOM.PL."ORF$="AKK.PL."THEN1850
1650 IF AP$="C"THEN1720
1660 IF AS$="I"ANDA$(Z,2)="D"THEN1760
1670 IF AS$="I"ANDI1$<>"J"THEN1760
1680 IF AD$="D"ORAK$="P"THEN1800
1690 IF AP$="A"ANDF$="NOM.PL."ANDF$<>C$ THEN F$="DAT.S.":GOTO1740
1700 IF AP$="A"OR AP$="H"THEN1740
1710 GOTO1800
1720 IF A$(Z,2)="B"ORA$(Z,2)="D"OR I1$<>"J"THEN1760
1730 GOTO1800
1740 IF F$="GEN.S."ORF$="DAT.S."THEN1830
1750 GOTO 1800
1760 IFF$="ABL.S."ORF$="DAT.S."THEN1840
1770 IF AP$="B"AND I1$<>"J"THEN1790
1780 IF AP$="C"OR A$(Z,2)<>"B"THEN1800
1790 IF F$="GEN.S."ORF$="NOM.PL."THEN1860
1800 IF F$=C$ THEN1950
1810 GOTO1960
1820 CA$="DAT.PL.":CB$="ABL.PL.":GOTO1870
1830 CA$="GEN.S.":CB$="DAT.S.":GOTO1870
1840 CA$="DAT.S.":CB$="ABL.S.":GOTO1870
1850 CA$="NOM.PL.":CB$="AKK.PL.":GOTO1870
1860 CA$="NOM.PL.":CB$="GEN.S.":GOTO1870
1870 PRINT"  ODER: [158]";:INPUT#2,FA$:PRINTCH$
1880 IFAP$="A"ANDF$<>"GEN.S."ANDFA$="NOM.PL."THENFA$="GEN.S."
1890 IFAP$="A"ANDF$="GEN.S."ANDFA$="NOM.PL."THENFA$="DAT.S."
1900 IF FA$= CA$ OR FA$=CB$ THEN 2000
1910 IFCA$<>C$THENCD$=CA$
1920 IFCB$<>C$THENCD$=CB$
1930 GOTO 2090
1940 PRINT
1950 GOSUB5220:PRINT"RICHTIG!":P=P+1:GOTO2120
1960 IFPP>9 THEN1980
1970 R=R+1:R$(R)=SA$:V$(R)=C$:PP=PP+1
1980 PRINT"[154]LEIDER FALSCH!RICHTIG IST:"
1990 PRINT"NOM.S.:";NS$;"[146]KASUS:";C$:PRINT"":GOTO 2120
2000 IF CA$<>C$ THEN CD$=CA$
2010 IF CB$<>C$ THEN CD$=CB$
2020 IF F$=C$ THEN 2040
2030 IF F$=CD$ THEN 2060
2040 IF FA$=CD$ THEN 2110
2050 GOTO2070
2060 IF FA$=C$ THEN 2110
2070 IFPP>10 THEN2090
2080 R=R+1:R$(R)=SA$:V$(R)=C$+Q$+CD$:PP=PP+1
2090 PRINT"[154]LEIDER FALSCH;RICHTIG IST:"
2100 PRINT"[154]  NOM.S.: ";NS$:PRINT"[154][146]KASUS: ";C$;"[154] UND: ";CD$:GOTO2120
2110 GOSUB5220:PRINT"RICHTIG!":P=P+1
2120 GOSUB 5460
2130 PRINTM$
2140 NEXTI
2150 GOSUB 4920
2160 GOTO 1450
2170 M$="[147][154]   FORMEN BILDEN LASSEN[146]":PRINTM$:I1$="":POKE53280,0
2180 PRINT "GEWUENSCHTES SUBSTANTIV [158]";:INPUT#2,S$:PRINTCH$
2190 GOSUB 4790
2200 PRINTM$:PRINT"  ";S$
2210 PRINT"[154]GEWUENSCHTER KASUS (Z.B.:DAT.S.)"
2220 PRINT"  [158]";:INPUT#2,Y$:PRINTCH$
2230 IFY$="GEN.S."THENY=1:GOTO2330
2240 IFY$="DAT.S."THENY=2:GOTO2330
2250 IFY$="AKK.S."THENY=3:GOTO2330
2260 IFY$="ABL.S."THENY=4:GOTO2330
2270 IFY$="NOM.PL."THENY=5:GOTO2330
2280 IFY$="GEN.PL."THENY=6:GOTO2330
2290 IFY$="DAT.PL."THENY=7:GOTO2330
2300 IFY$="AKK.PL."THENY=8:GOTO2330
2310 IFY$="ABL.PL."THENY=9:GOTO2330
2320 PRINT"  [154]EINGABE VON FALSCHEM FORMAT":GOTO 2210
2330 IFY<5ANDAS$="P"THENY=Y+5
2340 GOSUB 2430
2350 PRINT M$
2360 PRINT"  DIE FORMENBESTIMMUNG LAUTET:"
2370 PRINT"  ";C$;"[154] VON ";A$(X,0);":"
2380 IF Y=3 AND A$(X,3)="N"THEN2400
2390 PRINT"";A$(X,1)+B$:GOTO2410
2400 PRINT"";A$(X,0)
2410 GOSUB 5030
2420 GOTO2170
2430 AP$=LEFT$(A$(X,2),1):AS$=RIGHT$(A$(X,2),1)
2440 IF Y=1 THEN 2530
2450 IF Y=2 THEN 2600
2460 IF Y=3 THEN 2680
2470 IF Y=4 THEN 2740
2480 IF Y=5 THEN 2810
2490 IF Y=6 THEN 2890
2500 IF Y=7 THEN 2970
2510 IF Y=8 THEN 3040
2520 IF Y=9 THEN 3120
2530 C$="GEN.S."
2540 IF AP$="A" THEN3140
2550 IF AP$="B" THEN3190
2560 IF AP$="C" THEN 3190
2570 IF AP$="G" THEN3250
2580 IF AP$="H" THEN3300
2590 B$="IS":GOTO3350
2600 C$="DAT.S."
2610 IF AP$="A" THEN 3140
2620 IF AP$="D" THEN 3190
2630 IF AP$="E" THEN 3190
2640 IF AP$="F" THEN 3190
2650 IF AP$="G" THEN 3270
2660 IF AP$="H" THEN 3300
2670 B$="O":GOTO3350
2680 C$="AKK.S."
2690 IF A$(X,3)="N" THEN SA$=NS$:RETURN
2700 IF AP$="A" THEN3150
2710 IF AS$="I" THEN 3340
2720 IF AP$="G"OR AP$="B" THEN 3200
2730 B$="EM":GOTO3350
2740 C$="ABL.S."
2750 IF AP$="A" THEN 3160
2760 IF AS$="I" THEN 3190
2770 IF AP$="E"ORAP$="D"THEN 3220
2780 IF AP$="F"ORAP$="H"THEN 3220
2790 IF AP$="G" THEN 3280
2800 B$="O":GOTO3350
2810 C$="NOM.PL."
2820 IF AS$="I"ANDA$(X,3)="N"THEN 3330
2830 IF AP$="A" THEN 3140
2840 IF AP$="B" THEN 3190
2850 IF AP$="E"OR AP$="C" THEN 3160
2860 IF AP$="G"ANDA$(X,3)="N"THEN3260
2870 IF AP$="G" THEN 3250
2880 B$="ES":GOTO3350
2890 C$="GEN.PL."
2900 IF AP$="A" THEN 3170
2910 IF AP$="D" THEN 3200
2920 IF AP$="E" THEN 3200
2930 IF AP$="F" THEN 3240
2940 IF AP$="G" THEN 3290
2950 IF AP$="H" THEN 3310
2960 B$="ORUM":GOTO3350
2970 C$="DAT.PL."
2980 IF AP$="D" THEN 3230
2990 IF AP$="E" THEN 3230
3000 IF AP$="F" THEN 3230
3010 IF AP$="G" THEN 3230
3020 IF AP$="H" THEN 3320
3030 B$="IS":GOTO3350
3040 C$="AKK.PL."
3050 IF AS$="I"ANDA$(X,3)="N"THEN 3330
3060 IF AP$="A" THEN 3180
3070 IF AP$="B" THEN 3210
3080 IF AP$="E" ORAP$="C"THEN 3160
3090 IF AP$="G"ANDA$(X,3)="N"THEN3260
3100 IF AP$="G" THEN 3250
3110 B$="ES":GOTO3350
3120 C$="ABL.PL."
3130 GOTO 2980
3140 B$="AE":GOTO3350
3150 B$="AM":GOTO3350
3160 B$="A":GOTO3350
3170 B$="ARUM":GOTO3350
3180 B$="AS":GOTO3350
3190 B$="I":GOTO3350
3200 B$="UM":GOTO3350
3210 B$="OS":GOTO 3350
3220 B$="E":GOTO3350
3230 B$="IBUS":GOTO3350
3240 B$="IUM":GOTO3350
3250 B$="US":GOTO3350
3260 B$="UA":GOTO3350
3270 B$="UI":GOTO3350
3280 B$="U":GOTO3350
3290 B$="UUM":GOTO3350
3300 B$="EI":GOTO 3350
3310 B$="ERUM":GOTO3350
3320 B$="EBUS":GOTO3350
3330 B$="IA":GOTO3350
3340 B$="IM":GOTO3350
3350 IF I1$="J"THEN3380
3360 A$(Z,1)="":A$(Z,2)="":AD$="":AK$=""
3370 SA$=A$(X,1)+B$:PRINT:RETURN
3380 IF AP$="B"ANDA$(Z,2)="B"ANDA$(X,3)="M"THENO$=B$:GOTO4020
3390 IF AP$="A"ANDA$(Z,2)="B"ANDA$(X,3)="F"THENO$=B$:GOTO4020
3400 IF AP$="C"ANDA$(Z,2)="B"THENO$=B$:GOTO4020
3410 AD$=LEFT$(A$(Z,2),1):AK$=RIGHT$(A$(Z,2),1)
3420 IF Y=1ANDAD$="D"THEN3870
3430 IF Y=1ANDAK$="P"THEN3850
3440 IF Y=2ANDAD$="D"THEN3820
3450 IF Y=2ANDAK$="P"THEN3820
3460 IF Y=6ANDAD$="D"THEN3900
3470 IF Y=4ANDAD$="D"THEN3810
3480 IF Y=7ANDAD$="D"THEN3920
3490 IF Y=9ANDAD$="D"THEN3920
3500 IF Y=3ANDAD$="D"THEN3880
3510 IF Y=5ANDAD$="D"THEN3640
3520 IF Y=8ANDAD$="D"THEN3640
3530 IF Y=7 ANDAD$="B"THEN3870
3540 IF Y=9 ANDAD$="B"THEN3870
3550 IF Y=1 ANDAD$="B"THEN3660
3560 IF Y=2 ANDAD$="B"THEN3670
3570 IF Y=3 ANDAD$="B"THEN3690
3580 IF Y=4 ANDAD$="B"THEN3710
3590 IF Y=6 ANDAD$="B"THEN3730
3600 IF Y=5 ANDAD$="B"THEN3960
3610 IF Y=8 ANDAD$="B"THEN3990
3620 IF A$(X,3)="M"ORA$(X,3)="F"THEN3880
3630 IF A$(X,3)="N"THENO$=A$(Z,0):GOTO4020
3640 IF A$(X,3)="M"ORA$(X,3)="F"THEN3890
3650 IF A$(X,3)="N"THEN3930
3660 IF A$(X,3)="M"ORA$(X,3)="N"THEN3810
3670 IF A$(X,3)="M"ORA$(X,3)="N"THEN3950
3680 IF A$(X,3)="F"THEN3760
3690 IF A$(X,3)="M"ORA$(X,3)="N"THEN3830
3700 IF A$(X,3)="F"THEN3770
3710 IF A$(X,3)="M"ORA$(X,3)="N"THEN3950
3720 IF A$(X,3)="F"THEN3780
3730 IF A$(X,3)="M"ORA$(X,3)="N"THEN3860
3740 IF A$(X,3)="F"THEN3790
3750 GOTO3960
3760 O$="AE":GOTO4020
3770 O$="AM":GOTO4020
3780 O$="A":GOTO4020
3790 O$="ARUM":GOTO4020
3800 O$="AS":GOTO4020
3810 IFY=4ANDAK$="K"THENO$="E":GOTO4020
3820 O$="I":GOTO4020
3830 O$="UM":GOTO4020
3840 O$="OS":GOTO4020
3850 O$="IUS":GOTO4020
3860 O$="ORUM":GOTO4020
3870 O$="IS":GOTO4020
3880 O$="EM":GOTO4020
3890 O$="ES":GOTO4020
3900 IFAK$="K"THENO$="UM":GOTO4020
3910 O$="IUM":GOTO4020
3920 O$="IBUS":GOTO4020
3930 IFAK$="K"THENO$="A":GOTO4020
3940 O$="IA":GOTO4020
3950 O$="O":GOTO4020
3960 IF A$(X,3)="F"THEN3760
3970 IF A$(X,3)="M"THEN3810
3980 IF A$(X,3)="N"THEN3780
3990 IF A$(X,3)="N"THEN3780
4000 IF A$(X,3)="M"THEN3840
4010 IF A$(X,3)="F"THEN3800
4020 PRINT
4030 SA$=A$(X,1)+B$+Q$+A$(Z,1)+O$
4040 RETURN
4050 IF FR$="F"THEN4090
4060 X=RND(0)*AZ
4070 IF I1$<>"J"THEN4160
4080 Z=RND(0)*BZ+AZ:GOTO4160
4090 IF BE=1THENX=RND(0)*85+1:GOTO4130
4100 IF BE=2THENX=RND(0)*59+1:GOTO4130
4110 IF BE=3THENX=RND(0)*42+1:GOTO4130
4120 IF BE=4THENX=RND(0)*21+1
4130 IF I1$<>"J"THEN 4160
4140 IF BE>2THEN Z=RND(0)*15+86:GOTO4160
4150 Z=RND(0)*26+86
4160 AP$=LEFT$(A$(X,2),1):AS$=RIGHT$(A$(X,2),1)
4170 IF AS$="S"THENY=INT(4*RND(1))+1:GOTO4200
4180 IF AS$="P"THENY=5:GOSUB2430:AS$="":NS$=SA$:Y=INT(4*RND(1))+6:RETURN
4190 Y=INT(9*RND(1))+1
4200 IF I1$<>"J"ORAJ$="N"THEN4310
4210 AD$=LEFT$(A$(Z,2),1):AK$=RIGHT$(A$(Z,2),1)
4220 IF A$(Z,3)="EI"ORA$(X,3)="M"THEN4320
4230 IFA$(X,3)="F"ANDAD$="B"THENAB$="A":GOTO4300
4240 IFA$(X,3)="F"ANDA$(Z,2)="DK"THEN4320
4250 IFA$(X,3)="F"ANDAD$="D"THENAB$="IS":GOTO4300
4260 IFA$(X,3)="N"ANDA$(Z,2)="D"THENAB$="E":GOTO4300
4270 IFAK$="K"THENAB$="US":A=LEN(A$(Z,1)):C=A-2:A1$=LEFT$(A$(Z,1),C):GOTO4330
4280 IFA$(X,3)="N"ANDAD$="B"THENAB$="UM":GOTO4300
4290 GOTO4320
4300 AC$=A$(Z,1)+AB$:NS$=A$(X,0)+Q$+AC$:GOTO 4340
4310 NS$=A$(X,0):GOTO4340
4320 NS$=A$(X,0)+Q$+A$(Z,0):GOTO4340
4330 AC$=A1$+AB$:NS$=A$(X,0)+Q$+AC$
4340 RETURN
4350 PRINT"[147][154]      WAHLMOEGLICHKEITEN":Z=120:X=120
4360 INPUT " MIT ADJEKTIV (J/N)";I1$
4370 PRINT" 1) ALLE DEKLINATIONEN"
4380 PRINT" 2) A-/O-/KONS.DEKL.(INCL.MISCHFORM)"
4390 PRINT" 3) NUR MASC.UND FEM.DER A-/O-/KONS.DEKL"
4400 PRINT" 4) NUR A-/O-DEKLINATION"
4410 PRINT" ZAHL 1-4 EINGEBEN ":POKE198,0:WAIT198,1:GETBE$:BE=VAL(BE$)
4420 IFBE<1ORBE>4THEN4410
4430 RETURN
4440 A=1:B=3:C=7
4450 OPEN A,B,C
4460 POKE53280,6:PRINT"[154][147]"
4470 PRINT#A, "  ANIMA [154](A-DEKLINATION)"
4480 PRINT#A, "  ANIM   [158]-A  -AE    -AE   -AM  -A"
4490 PRINT#A, "         -AE -ARUM  -IS   -AS  -IS[154]"
4500 PRINT#A, "  HORTUS/PUER[154];(O-DEKLINATION)"
4510 PRINT#A, "  HORT   [158]-US -I     -O    -UM  -O"
4520 PRINT#A, "         -I  -ORUM  -IS   -OS  -IS[154]"
4530 PRINT#A, "  TEMPLUM[154]; (O-DEKLINATION)"
4540 PRINT#A, "  TEMPL  [158]-UM -I     -O    -UM  -O"
4550 PRINT#A, "         -A  -ORUM  -IS   -A   -IS[154]"
4560 PRINT#A, "  PALUS [154](KONS.DEKLINATION)"
4570 PRINT#A, "  PALUD     [158] -IS    -I    -EM  -E"
4580 PRINT#A, "         -ES -UM    -IBUS -ES  -IBUS[154]"
4590 PRINT#A, "  TEMPUS [154](KONS.DEKL.NEUTRUM)"
4600 PRINT#A, "  TEMPOR     [158]-IS    -I  TEMPUS[146] -E"
4610 PRINT#A, "         -A  -UM    -IBUS -A   -IBUS[154]"
4620 PRINT#A, "  ARX [154](KONS.DEKL.MISCHFORM)"
4630 PRINT#A, "  ARC        [158]-IS    -I    -EM  -E"
4640 PRINT#A, "         -ES -IUM   -IBUS -ES  -IBUS[154]"
4650 PRINT#A, "  SENATUS [154](U-DEKLINATION)"
4660 PRINT#A, "  SENAT  [158]-US -US    -UI   -UM  -U"
4670 PRINT#A, "         -US -UUM   -IBUS -US  -IBUS[154]"
4680 PRINT#A, "  DIES [154](E-DEKLINATION)"
4690 PRINT#A, "  DI     [158]-ES -EI    -EI   -EM  -E"
4700 PRINT#A, "         -ES -ERUM  -EBUS -ES  -EBUS[154]"
4710 CLOSEA
4720 IF B=4 THEN460
4730 INPUT"WIRD AUSDRUCK GEWUENSCHT (J/N)";I$
4740 IF I$<>"J" THEN460
4750 INPUT"DRUCKER BETRIEBSBEREIT";J$
4760 IF J$<>"J" THEN460
4770 A=7:B=4:C=0
4780 GOTO4450
4790 FOR X=0TO85:IF S$=A$(X,0)THEN4840
4800 NEXTX
4810 PRINT "[154] GEWUENSCHTES SUBSTANTIV NICHT IM"
4820 PRINT" DATENBESTAND":S$="N"
4830 GOSUB6610
4840 IF I1$<>"J"THEN4910
4860 FOR Z=86TO111:IFAJ$=A$(Z,0)THEN4910
4870 NEXTZ
4880 PRINTM$:PRINT "[154] GEWUENSCHTES ADJEKTIV NICHT IM"
4890 PRINT" DATENBESTAND":AJ$="N":I1$="N"
4900 GOSUB6610
4910 RETURN
4920 IFMM$="M"THEN5030
4930 PRINT"DU HAST ";P;" PUNKTE VON "
4940 PRINT"";H;"MOEGLICHEN ERREICHT"
4950 IFPP=0 THEN 5030
4960 PRINT"WIEDERHOLE FOLGENDE FORMEN:"
4970 PRINT
4980 FOR R=1 TO 10
4990 IF R$(R)=""THEN 5020
5000 PRINT"  ";V$(R);": ";R$(R);L1$
5010 V$(R)="":R$(R)=""
5020 NEXTR
5030 PP=0:R=0:E$="":INPUT "[154] NOCH EINMAL (J/N)";E$
5040 D1$="":D2$="":D3$="":D4$="":D5$="":D6$="":D7$="":D8$="":D9$=""
5050 IF E$<>"J"THEN460
5060 RETURN
5070 PRINT" BITTE 'M' EINGEBEN,WENN NUR 'MUENDLICH'"
5080 POKE198,0:WAIT198,1:GETMM$
5090 RETURN
5100 SI=54272:FL=SI:FH=SI+1:WM=SI+4:AM=SI+5:HM=SI+6:LM=SI+24
5110 POKELM,15:POKEAM,16+9:POKEHM,4*16+4:POKEFH,29:POKEFL,69:POKEWM,17
5120 FORTM=1TO500:NEXT
5130 POKEWM,0:POKEAM,0:POKEHM,0
5140 PRINT"[154]  FUER LOESUNG BITTE TASTE"
5150 POKE198,0:WAIT198,1:GETA$
5160 PRINT"[145]  MEINE LOESUNG LAUTET:      "
5170 IFEF$="2"THEN5190
5180 IFEF$="3"THEN5200
5190 PRINT"[158]  ";SA$:GOTO5210
5200 PRINT"[158]  ";C$;" VON [158]";NS$;"[146]"
5210 RETURN
5220 SI=54272:FL=SI:FH=SI+1:WM=SI+4:AM=SI+5:HM=SI+6:LM=SI+24:BM=29:CM=69
5230 FORZM=1TO3
5240 POKELM,15:POKEAM,16+9:POKEHM,4*16+4:POKEFH,BM:POKEFL,CM:POKEWM,17
5250 FORTM=1TO500:NEXT
5260 POKEWM,0:POKEAM,0:POKEHM,0
5270 IFZM=2THENBM=23:CM=55
5280 IFZM=3THENBM=39:CM=22
5290 NEXTZM
5300 RETURN
5310 PRINTL1$;"[147]":INPUT"  DATEI AUSDRUCKEN (J/N)";J$:IFJ$<>"J"THEN5430
5320 PRINT"  BITTE WARTEN"
5330 FORI=1TON
5340 FORK=NTOISTEP-1
5350 IFA$(K-1,0)<A$(K,0)THEN5370
5360 X$=A$(K-1,0):A$(K-1,0)=A$(K,0):A$(K,0)=X$
5370 NEXTK:NEXTI
5380 H=1:OPEN7,4,0:PRINT#7,"   DATEI (DEKLINATION)":PRINT#7
5390 FORI=0TON
5400 PRINT#7," ";A$(I,0);:IFI/5=HTHENH=H+1:PRINT#7
5410 NEXTI:PRINT#7:CLOSE7
5420 CLOSE2
5430 PRINT"  BITTE TASTE"
5440 GETA$:IFA$=""THEN5440
5450 GOTO6630
5460 PRINTL1$:PRINT"* BITTE TASTE DRUECKEN *"
5470 GETEQ$:IFEQ$=""THEN5470
5480 IFEQ$="[147]"THEN460
5490 RETURN
5500 DATA ANCILLA,ANCILL,A,F
5510 DATA FLUVIUS,FLUVI,B,M
5520 DATA EQUUS,EQU,B,M
5530 DATA DOMINUS,DOMIN,B,M
5540 DATA PUER,PUER,B,M
5550 DATA LIBER,LIBR,B,M
5560 DATA PORTA,PORT,A,F
5570 DATA SERVUS,SERV,B,M
5580 DATA PUELLA,PUELL,A,F
5590 DATA PUGNA,PUGN,A,F
5600 DATA CURA,CUR,A,F
5610 DATA VIR,VIR,B,M
5620 DATA DEUS,DE,B,M
5630 DATA POPULUS,POPUL,B,M
5640 DATA CAPTIVUS,CAPTIV,B,M
5650 DATA INSIDIAE,INSIDI,AP,F
5660 DATA POETA,POET,A,M
5670 DATA CAUSA,CAUS,A,F
5680 DATA CLEMENTIA,CLEMENTI,AS,F
5690 DATA AMICUS,AMIC,B,M
5700 DATA MORBUS,MORB,B,M
5710 DATA ORATOR,ORATOR,D,M
5720 DATA ARBOR,ARBOR,D,F
5730 DATA SOROR,SOROR,D,F
5740 DATA MATER,MATR,D,F
5750 DATA CONSUL,CONSUL,D,M
5760 DATA TERROR,TERROR,D,M
5770 DATA SALUS,SALUT,DS,F
5780 DATA MILES,MILIT,D,M
5790 DATA TIMOR,TIMOR,D,M
5800 DATA VIRTUS,VIRTUT,D,F
5810 DATA DUX,DUC,D,M
5820 DATA PAX,PAC,DS,F
5830 DATA REX,REG,D,M
5840 DATA LEX,LEG,D,F
5850 DATA CONIUNX,CONIUG,D,F
5860 DATA MOS,MOR,D,M
5870 DATA LAUS,LAUD,D,F
5880 DATA GENS,GENT,F,F
5890 DATA AETAS,AETAT,D,F
5900 DATA LIMES,LIMIT,D,M
5910 DATA MULTITUDO,MULTITUDIN,D,F
5920 DATA TEMPLUM,TEMPL,C,N
5930 DATA AURUM,AUR,CS,N
5940 DATA FORUM,FOR,C,N
5950 DATA CASTRA,CASTR,CP,N
5960 DATA FLUMEN,FLUMIN,E,N
5970 DATA GENUS,GENER,E,N
5980 DATA CARMEN,CARMIN,E,N
5990 DATA CORPUS,CORPOR,E,N
6000 DATA VULNUS,VULNER,E,N
6010 DATA TEMPUS,TEMPOR,E,N
6020 DATA FATUM,FAT,C,N
6030 DATA ODIUM,ODI,CS,N
6040 DATA PERICULUM,PERICUL,C,N
6050 DATA BELLUM,BELL,C,N
6060 DATA OPUS,OPER,E,N
6070 DATA NOMEN,NOMIN,E,N
6080 DATA IUS,IUR,E,N
6090 DATA URBS,URB,F,F
6100 DATA MARE,MAR,FI,N
6110 DATA NAVIS,NAV,F,F
6120 DATA ARS,ART,F,F
6130 DATA FINIS,FIN,F,M
6140 DATA ITER,ITINER,E,N
6150 DATA MONS,MONT,F,M
6160 DATA PARS,PART,F,F
6170 DATA CIVIS,CIV,F,M
6180 DATA ANIMAL,ANIMAL,FI,N
6190 DATA USUS,US,G,M
6200 DATA EXERCITUS,EXERCIT,G,M
6210 DATA ADITUS,ADIT,GS,M
6220 DATA SENATUS,SENAT,GS,M
6230 DATA MANUS,MAN,G,F
6240 DATA TURRIS,TURR,FI,F
6250 DATA PORTUS,PORT,G,M
6260 DATA MAGISTRATUS,MAGISTRAT,G,M
6270 DATA ASPECTUS,ASPECT,GS,M
6280 DATA RES,R,H,F
6290 DATA FIDES,FID,HS,F
6300 DATA SPES,SP,HS,F
6310 DATA DIES,DI,H,M
6320 DATA PLANITIES,PLANITI,H,F
6330 DATA ACIES,ACI,H,F
6340 DATA PERNICIES,PERNICI,HS,F
6350 DATA BONUS,BON,B,DR
6360 DATA PULCHER,PULCHR,B,DR
6370 DATA MALUS,MAL,B,DR
6380 DATA SAEVUS,SAEV,B,DR
6390 DATA LIBER,LIBER,B,DR
6400 DATA FIDUS,FID,B,DR
6410 DATA ROMANUS,ROMAN,B,DR
6420 DATA FIRMUS,FIRM,B,DR
6430 DATA ARMATUS,ARMAT,B,DR
6440 DATA PLENUS,PLEN,B,DR
6450 DATA MEUS,ME,B,DR
6460 DATA NOSTER,NOSTR,B,DR
6470 DATA VESTER,VESTR,B,DR
6480 DATA CAUTUS,CAUT,B,DR
6490 DATA MISER,MISER,B,DR
6500 DATA FELIX,FELIC,D,EI
6510 DATA AUDAX,AUDAC,D,EI
6520 DATA SAPIENS,SAPIENT,D,EI
6530 DATA CONSTANS,CONSTANT,D,EI
6540 DATA FORTIS,FORT,D,ZW
6550 DATA GRAVIS,GRAV,D,ZW
6560 DATA LEVIS,LEV,D,ZW
6570 DATA MOLLIS,MOLL,D,ZW
6580 DATA CELER,CELER,D,DR
6590 DATA ACER,ACR,D,DR
6600 DATA FEROX,FEROC,D,EI
6610 PRINT"         *** BITTE TASTE ***"
6620 POKE198,0:WAIT198,1:GETA$:RETURN
6630 END